1 files changed, 72 insertions, 0 deletions
diff --git a/sbe/image/linksbe.cmd b/sbe/image/linksbe.cmd
new file mode 100644
index 00000000..21957f8e
--- /dev/null
+++ b/sbe/image/linksbe.cmd
@@ -0,0 +1,72 @@
+
+// Need to do this so that elf32-powerpc is not modified!
+#undef powerpc
+
+#ifndef INITIAL_STACK_SIZE
+#define INITIAL_STACK_SIZE 256
+#endif
+
+OUTPUT_FORMAT(elf32-powerpc);
+
+MEMORY
+{
+// sram : ORIGIN = 0xFFF40000, LENGTH = 0xc0000
+ sram : ORIGIN = 0xffff0000, LENGTH = 0x10000
+}
+
+SECTIONS
+{
+    . = 0xffff0000;
+    .text          : {. = ALIGN(512); *(.vectors) *(.text)} > sram
+
+    ////////////////////////////////
+    // Read-only Data
+    ////////////////////////////////
+
+    . = ALIGN(8);
+    _RODATA_SECTION_BASE = .;
+
+    // SDA2 constant sections .sdata2 and .sbss2 must be adjacent to each
+    // other.  Our SDATA sections are small so we'll use strictly positive
+    // offsets. 
+
+    _SDA2_BASE_ = .;
+   .sdata2 . : { *(.sdata2) } > sram
+   .sbss2  . : { *(.sbss2) } > sram
+
+   // Other read-only data.  
+
+   .rodata . : { *(.rodata*) *(.got2) } > sram
+
+    _RODATA_SECTION_SIZE = . - _RODATA_SECTION_BASE;
+
+    ////////////////////////////////
+    // Read-write Data
+    ////////////////////////////////
+
+    . = ALIGN(8);
+    _DATA_SECTION_BASE = .;
+
+    // SDA sections .sdata and .sbss must be adjacent to each
+    // other.  Our SDATA sections are small so we'll use strictly positive
+    // offsets. 
+
+    _SDA_BASE_ = .;
+    .sdata  . : { *(.sdata)  } > sram
+    .sbss   . : { *(.sbss)   } > sram
+
+    // Other read-write data
+    // It's not clear why boot.S is generating empty .glink,.iplt
+
+   .rela   . : { *(.rela*) } > sram
+   .rwdata . : { *(.data) *(.bss) } > sram
+//  .iplt . : { *(.iplt) } > sram
+
+   _PK_INITIAL_STACK_LIMIT = .;
+   . = . + INITIAL_STACK_SIZE;
+   _PK_INITIAL_STACK = . - 1;
+
+    . = ALIGN(8);
+    _sbe_end = . - 0;
+
+}