meta-phosphor/recipes-phosphor/settings/phosphor-settings-read-settings-mrw-native.bb


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Generates MRW settings override yaml for phosphor-settings-manager
# The default YAML file, mrw-override-settings.yaml, is empty, therefore no
# settings will be overwritten. To override, modify mrw-override-settings.yaml.

SUMMARY = "Generates MRW settings override YAML for phosphor-settings-manager."
PR = "r1"
LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://${PHOSPHORBASE}/COPYING.apache-2.0;md5=34400b68072d710fecd0a2940a0d1658"

inherit native
inherit phosphor-settings-manager
inherit mrw-xml

DEPENDS += "mrw-native mrw-perl-tools-native"

SRC_URI += "file://mrw-override-settings.yaml"

S = "${WORKDIR}"

MRW_EXPRESSION_VARS ?= ""

do_install() {
    DEST=${D}${config_datadir}
    install -D mrw-override-settings.yaml ${DEST}/mrw-override-settings.yaml

    SETTINGS=${D}${settings_datadir}
    install -d ${SETTINGS}

    # gen_settings.pl replaces any MRW variables with their value
    ${bindir}/perl-native/perl \
        ${bindir}/gen_settings.pl \
        -i ${mrw_datadir}/${MRW_XML} \
        -s ${DEST}/mrw-override-settings.yaml \
        -o ${SETTINGS}/mrw-settings.override.yaml \
        ${MRW_EXPRESSION_VARS} \
        -f
}