[DebugInfo] Emit DWARF reference for DIVariable 'count' in DISubrange

Summary:
This patch implements the codegen of DWARF debug info for non-constant
'count' fields for DISubrange.

This is patch [2/3] in a series to extend LLVM's DISubrange Metadata
node to support debugging of C99 variable length arrays and vectors with
runtime length like the Scalable Vector Extension for AArch64. It is
also a first step towards representing more complex cases like arrays
in Fortran.

Reviewers: echristo, pcc, aprantl, dexonsmith, clayborg, kristof.beyls, dblaikie

Reviewed By: aprantl

Subscribers: fhahn, aemerson, rengolin, JDevlieghere, llvm-commits

Differential Revision: https://reviews.llvm.org/D41696

llvm-svn: 323323

1 files changed, 50 insertions, 0 deletions

diff --git a/llvm/test/DebugInfo/Generic/disubrange.ll b/llvm/test/DebugInfo/Generic/disubrange.ll
new file mode 100644
index 00000000000..76b0da79a38
--- /dev/null
+++ b/llvm/test/DebugInfo/Generic/disubrange.ll
@@ -0,0 +1,50 @@
+; RUN: rm -rf %t %t2
+; RUN: %llc_dwarf -O0 -filetype=obj < %s > %t
+; RUN: llvm-dwarfdump -name=vla_expr %t > %t2
+; RUN: llvm-dwarfdump -verbose %t >> %t2
+; RUN: cat %t2 | FileCheck %s
+
+; This test runs llvm-dwarfdump twice:
+; - First to get the debug entry for 'vla_expr'.
+; - Second to check that this is the entry referenced in DW_AT_count.
+; This way the test does not depend on the order in which DW_TAG_variables
+; are emitted.
+
+; CHECK:       [[NODE:[0-9a-zA-Zx]+]]: DW_TAG_variable [4]
+; CHECK-NEXT:  DW_AT_name {{.*}} "vla_expr"
+; CHECK:       DW_AT_count [DW_FORM_ref4]  (cu + {{.*}} => {[[NODE]]})
+
+define void @foo(i32 %n) !dbg !7 {
+entry:
+  call void @llvm.dbg.value(metadata i32 %n, i64 0, metadata !12, metadata !19), !dbg !20
+  ret void, !dbg !21
+}
+
+declare void @llvm.dbg.value(metadata, i64, metadata, metadata)
+
+!llvm.dbg.cu = !{!0}
+!llvm.module.flags = !{!3, !4, !5}
+!llvm.ident = !{!6}
+
+!0 = distinct !DICompileUnit(language: DW_LANG_C99, file: !1, producer: "clang version 5.0.1", isOptimized: true, runtimeVersion: 0, emissionKind: FullDebug, enums: !2)
+!1 = !DIFile(filename: "vla.c", directory: "/path/to")
+!2 = !{}
+!3 = !{i32 2, !"Dwarf Version", i32 4}
+!4 = !{i32 2, !"Debug Info Version", i32 3}
+!5 = !{i32 1, !"wchar_size", i32 4}
+!6 = !{!"clang version 5.0.1"}
+!7 = distinct !DISubprogram(name: "foo", scope: !1, file: !1, line: 20, type: !8, isLocal: false, isDefinition: true, scopeLine: 20, flags: DIFlagPrototyped, isOptimized: true, unit: !0, variables: !11)
+!8 = !DISubroutineType(types: !9)
+!9 = !{null, !10}
+!10 = !DIBasicType(name: "int", size: 32, encoding: DW_ATE_signed)
+!11 = !{!12, !13, !15}
+!12 = !DILocalVariable(name: "n", arg: 1, scope: !7, file: !1, line: 20, type: !10)
+!13 = !DILocalVariable(name: "vla_expr", scope: !7, file: !1, line: 21, type: !14)
+!14 = !DIBasicType(name: "long unsigned int", size: 64, encoding: DW_ATE_unsigned)
+!15 = !DILocalVariable(name: "vla", scope: !7, file: !1, line: 21, type: !16)
+!16 = !DICompositeType(tag: DW_TAG_array_type, baseType: !10, align: 32, elements: !17)
+!17 = !{!18, !18}
+!18 = !DISubrange(count: !13)
+!19 = !DIExpression()
+!20 = !DILocation(line: 20, column: 14, scope: !7)
+!21 = !DILocation(line: 22, column: 1, scope: !7)