blob: 5f1f36d2a6720cbc382b1e10b8f3f623e5e490e9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
SUMMARY = "Phosphor LED Group Management Daemon"
DESCRIPTION = "Daemon to cater to triggering actions on LED groups"
PR = "r1"
require ${PN}.inc
inherit autotools pkgconfig pythonnative
inherit obmc-phosphor-dbus-service obmc-phosphor-systemd
LED_MGR_PACKAGES = " \
${PN}-ledmanager \
${PN}-faultmonitor \
"
PACKAGES += "${LED_MGR_PACKAGES}"
PACKAGES_remove = "${PN}"
DBUS_PACKAGES = "${PN}-ledmanager"
SYSTEMD_PACKAGES = "${LED_MGR_PACKAGES}"
RDEPENDS_${PN}-dev = "${LED_MGR_PACKAGES}"
RDEPENDS_${PN}-staticdev = "${LED_MGR_PACKAGES}"
DEPENDS += "python-pyyaml-native"
DEPENDS += "autoconf-archive-native"
DEPENDS += "sdbusplus sdbusplus-native"
DEPENDS += "phosphor-logging"
DEPENDS += "virtual/${PN}-config-native"
RDEPENDS_${PN}-ledmanager += "libsystemd"
RDEPENDS_${PN}-ledmanager += "phosphor-logging"
RDEPENDS_${PN}-faultmonitor += "libsystemd"
RDEPENDS_${PN}-faultmonitor += "phosphor-logging"
S = "${WORKDIR}/git"
FILES_${PN}-ledmanager += "${sbindir}/phosphor-ledmanager"
FILES_${PN}-faultmonitor += "${sbindir}/phosphor-fru-fault-monitor"
DBUS_SERVICE_${PN}-ledmanager += "xyz.openbmc_project.LED.GroupManager.service"
SYSTEMD_SERVICE_${PN}-ledmanager += "obmc-led-group-start@.service obmc-led-group-stop@.service"
SYSTEMD_SERVICE_${PN}-faultmonitor += "obmc-fru-fault-monitor.service"
SYSTEMD_LINK_${PN}-ledmanager += "../obmc-led-group-start@.service:${SYSTEMD_DEFAULT_TARGET}.wants/obmc-led-group-start@bmc_booted.service"
STATES = "start stop"
TMPLFMT = "obmc-led-group-{0}@.service"
TGTFMT = "obmc-power-{0}@0.target"
INSTFMT = "obmc-led-group-{0}@power_on.service"
FMT = "../${TMPLFMT}:${TGTFMT}.wants/${INSTFMT}"
SYSTEMD_LINK_${PN}-ledmanager += "${@compose_list(d, 'FMT', 'STATES')}"
EXTRA_OECONF = "YAML_PATH=${STAGING_DATADIR_NATIVE}/${PN}"
|
