Add recipe for phosphor-snmp

Phosphor-snmp provides the D-Bus service named network-snmp-conf
which is used to configure the snmp manager details.

Phosphor-snmp also provides the lib which is used by the client
to send the snmp trap.

Phosphor-snmp uses the net-snmp libs to send the trap.

net-snmp provides the following packages
net-snmp-libs,net-snmp-server, net-snmp-client,
net-snmp-server-snmpd-netsnmp-server-snmptrapd.

To send a trap we are interested only in the net-snmp-libs.
By default the net-snmp-libs is having the code enabled for server
sepcific functions which makes the libs heavy.

This commit adds the recipe for phosphor-snmp and the service file
for D-Bus service(network-snmp-conf) and disables those features
from net-snmp which are specfic for MIB parsing,snmpd and snmptrapd.

However this features may be required if we start using
the snmp agent functionality.

Change-Id: I6ff36fcd378db2f506b0621569693d66d7de79e9
Signed-off-by: Ratan Gupta <ratagupt@in.ibm.com>

3 files changed, 57 insertions, 0 deletions

diff --git a/meta-phosphor/common/recipes-connectivity/net-snmp/net-snmp_%.bbappend b/meta-phosphor/common/recipes-connectivity/net-snmp/net-snmp_%.bbappend
new file mode 100644
index 000000000..03c5c8878
--- /dev/null
+++ b/meta-phosphor/common/recipes-connectivity/net-snmp/net-snmp_%.bbappend
@@ -0,0 +1,13 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+
+EXTRA_OECONF += "--disable-mib-loading --disable-agent --disable-applications \
+--disable-manuals --disable-scripts --disable-mibs  --disable-embedded-perl \
+--disable-perl-cc-checks --disable-libtool-lock --disable-debugging \
+--disable-snmpv1 --disable-des --disable-privacy --disable-md5 \
+--disable-snmptrapd-subagent --disable-set-support --disable-deprecated"
+
+do_install_append() {
+    rm -f ${D}${libdir}/libnetsnmpmibs.so.*
+    rm -f ${D}${libdir}/libnetsnmphelpers.so.*
+    rm -f ${D}${libdir}/libnetsnmpagent.so.*
+}
diff --git a/meta-phosphor/common/recipes-phosphor/network/phosphor-snmp/xyz.openbmc_project.Network.SNMP.service b/meta-phosphor/common/recipes-phosphor/network/phosphor-snmp/xyz.openbmc_project.Network.SNMP.service
new file mode 100644
index 000000000..f5a1d7274
--- /dev/null
+++ b/meta-phosphor/common/recipes-phosphor/network/phosphor-snmp/xyz.openbmc_project.Network.SNMP.service
@@ -0,0 +1,13 @@
+[Unit]
+Description=Phosphor SNMP conf Manager
+After=obmc-mapper.target
+
+[Service]
+ExecStart=/usr/bin/env phosphor-network-snmpconf
+SyslogIdentifier=phosphor-network-snmpconf
+Restart=always
+Type=dbus
+BusName=xyz.openbmc_project.Network.SNMP
+
+[Install]
+WantedBy={SYSTEMD_DEFAULT_TARGET}
diff --git a/meta-phosphor/common/recipes-phosphor/network/phosphor-snmp_git.bb b/meta-phosphor/common/recipes-phosphor/network/phosphor-snmp_git.bb
new file mode 100644
index 000000000..96e244876
--- /dev/null
+++ b/meta-phosphor/common/recipes-phosphor/network/phosphor-snmp_git.bb
@@ -0,0 +1,31 @@
+SUMMARY = "SNMP Manager Configuration"
+DESCRIPTION = "SNMP Manager Configuration."
+HOMEPAGE = "http://github.com/openbmc/phosphor-snmp"
+PR = "r1"
+PV = "0.1+git${SRCPV}"
+
+inherit autotools pkgconfig
+inherit pythonnative
+inherit obmc-phosphor-dbus-service
+
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${WORKDIR}/git/LICENSE;md5=86d3f3a95c324c9479bd8986968f4327"
+
+SRC_URI += "git://github.com/openbmc/phosphor-snmp"
+SRCREV = "3f6e2861d7291deea070336abb829c8538dcc7aa"
+
+DBUS_SERVICE_${PN} += "xyz.openbmc_project.Network.SNMP.service"
+
+DEPENDS += "systemd"
+DEPENDS += "autoconf-archive-native"
+DEPENDS += "sdbusplus sdbusplus-native"
+DEPENDS += "phosphor-dbus-interfaces phosphor-dbus-interfaces-native"
+DEPENDS += "phosphor-logging"
+DEPENDS += "net-snmp"
+
+RDEPENDS_${PN} += "libsystemd"
+RDEPENDS_${PN} += "sdbusplus phosphor-dbus-interfaces"
+RDEPENDS_${PN} += "phosphor-logging"
+RDEPENDS_${PN} += "net-snmp-libs"
+
+S = "${WORKDIR}/git"