phosphor-state-manager: remove daemon duplication

The phosphor-state-manager repository builds [at least] two executables:
    * phosphor-host-state-manager
    * phosphor-chassis-state-manager

phosphor-host-state-manager.bb and phosphor-chassis-state-manager.bb
were effectively the exact same file and had no assignment of
executables to files.  The result was that both packages installed both
daemons and caused an installation collision.

Combine the two recipes into a single recipe with the correct package
relationship for each executable.

Change-Id: I76a1e598bebc5090ae374271bbd5e8e32967cb43
Signed-off-by: Patrick Williams <patrick@stwcx.xyz>

6 files changed, 46 insertions, 54 deletions

diff --git a/meta-phosphor/common/recipes-phosphor/state/phosphor-chassis-state-manager/xyz.openbmc_project.State.Chassis.service b/meta-phosphor/common/recipes-phosphor/state/files/xyz.openbmc_project.State.Chassis.service
index 5133fad04..5133fad04 100644
--- a/meta-phosphor/common/recipes-phosphor/state/phosphor-chassis-state-manager/xyz.openbmc_project.State.Chassis.service
+++ b/meta-phosphor/common/recipes-phosphor/state/files/xyz.openbmc_project.State.Chassis.service
diff --git a/meta-phosphor/common/recipes-phosphor/state/phosphor-host-state-manager/xyz.openbmc_project.State.Host.service b/meta-phosphor/common/recipes-phosphor/state/files/xyz.openbmc_project.State.Host.service
index 8fd2ed351..8fd2ed351 100644
--- a/meta-phosphor/common/recipes-phosphor/state/phosphor-host-state-manager/xyz.openbmc_project.State.Host.service
+++ b/meta-phosphor/common/recipes-phosphor/state/files/xyz.openbmc_project.State.Host.service
diff --git a/meta-phosphor/common/recipes-phosphor/state/phosphor-chassis-state-manager.bb b/meta-phosphor/common/recipes-phosphor/state/phosphor-chassis-state-manager.bb
deleted file mode 100644
index 015f83cb0..000000000
--- a/meta-phosphor/common/recipes-phosphor/state/phosphor-chassis-state-manager.bb
+++ /dev/null
@@ -1,26 +0,0 @@
-SUMMARY = "Phosphor Chassis State Management"
-DESCRIPTION = "Phosphor Chassis State Manager provides a chassis state \
-object which manages the chassis's in the system. It is suitable for use on \
-a wide variety of OpenBMC platforms."
-HOMEPAGE = "https://github.com/openbmc/phosphor-state-manager"
-PR = "r1"
-LICENSE = "Apache-2.0"
-LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
-
-inherit autotools pkgconfig
-inherit obmc-phosphor-dbus-service
-
-DBUS_SERVICE_${PN} += "xyz.openbmc_project.State.Chassis.service"
-
-RDEPENDS_${PN} += "libsystemd"
-DEPENDS += "autoconf-archive-native"
-DEPENDS += "sdbusplus"
-DEPENDS += "phosphor-logging"
-
-PROVIDES += "virtual/obmc-chassis-state-mgmt"
-RPROVIDES_${PN} += "virtual-obmc-chassis-state-mgmt"
-
-SRC_URI += "git://github.com/openbmc/phosphor-state-manager"
-SRCREV = "6e0b50936735faac96db2f20fe84ffd0733750a9"
-
-S = "${WORKDIR}/git"
diff --git a/meta-phosphor/common/recipes-phosphor/state/phosphor-host-state-manager.bb b/meta-phosphor/common/recipes-phosphor/state/phosphor-host-state-manager.bb
deleted file mode 100644
index 85f2873bf..000000000
--- a/meta-phosphor/common/recipes-phosphor/state/phosphor-host-state-manager.bb
+++ /dev/null
@@ -1,26 +0,0 @@
-SUMMARY = "Phosphor Host State Management"
-DESCRIPTION = "Phosphor Host State Manager provides a host state \
-object which manages the hosts in the system. It is suitable for use on \
-a wide variety of OpenBMC platforms."
-HOMEPAGE = "https://github.com/openbmc/phosphor-state-manager"
-PR = "r1"
-LICENSE = "Apache-2.0"
-LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
-
-inherit autotools pkgconfig
-inherit obmc-phosphor-dbus-service
-
-DBUS_SERVICE_${PN} += "xyz.openbmc_project.State.Host.service"
-
-RDEPENDS_${PN} += "libsystemd"
-DEPENDS += "autoconf-archive-native"
-DEPENDS += "sdbusplus"
-DEPENDS += "phosphor-logging"
-
-PROVIDES += "virtual/obmc-host-state-mgmt"
-RPROVIDES_${PN} += "virtual-obmc-host-state-mgmt"
-
-SRC_URI += "git://github.com/openbmc/phosphor-state-manager"
-SRCREV = "6e0b50936735faac96db2f20fe84ffd0733750a9"
-
-S = "${WORKDIR}/git"
diff --git a/meta-phosphor/common/recipes-phosphor/state/phosphor-state-manager.bb b/meta-phosphor/common/recipes-phosphor/state/phosphor-state-manager.bb
new file mode 100644
index 000000000..17c58e8e4
--- /dev/null
+++ b/meta-phosphor/common/recipes-phosphor/state/phosphor-state-manager.bb
@@ -0,0 +1,44 @@
+SUMMARY = "Phosphor State Management"
+DESCRIPTION = "Phosphor State Manager provides a set of system state \
+management daemons. It is suitable for use on a wide variety of OpenBMC \
+platforms."
+HOMEPAGE = "https://github.com/openbmc/phosphor-state-manager"
+PR = "r1"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=e3fc50a88d0a364313df4b21ef20c29e"
+
+STATE_MGR_PACKAGES = " \
+    ${PN}-host \
+    ${PN}-chassis \
+"
+PACKAGES =+ "${STATE_MGR_PACKAGES}"
+DBUS_PACKAGES = "${STATE_MGR_PACKAGES}"
+
+# Set SYSTEMD_PACKAGES to empty because we do not want ${PN} and DBUS_PACKAGES
+# handles the rest.
+SYSTEMD_PACKAGES = ""
+
+inherit autotools pkgconfig
+inherit obmc-phosphor-dbus-service
+
+DEPENDS += "autoconf-archive-native"
+DEPENDS += "sdbusplus"
+DEPENDS += "phosphor-logging"
+
+RDEPENDS_${PN}-host += "libsystemd"
+RDEPENDS_${PN}-chassis += "libsystemd"
+
+PROVIDES += "virtual/obmc-host-state-mgmt"
+RPROVIDES_${PN}-host += "virtual-obmc-host-state-mgmt"
+FILES_${PN}-host = "${sbindir}/phosphor-host-state-manager"
+DBUS_SERVICE_${PN}-host += "xyz.openbmc_project.State.Host.service"
+
+PROVIDES += "virtual/obmc-chassis-state-mgmt"
+RPROVIDES_${PN}-chassis += "virtual-obmc-chassis-state-mgmt"
+FILES_${PN}-chassis = "${sbindir}/phosphor-chassis-state-manager"
+DBUS_SERVICE_${PN}-chassis += "xyz.openbmc_project.State.Chassis.service"
+
+SRC_URI += "git://github.com/openbmc/phosphor-state-manager"
+SRCREV = "6e0b50936735faac96db2f20fe84ffd0733750a9"
+
+S = "${WORKDIR}/git"
diff --git a/meta-phosphor/conf/distro/include/phosphor-defaults.inc b/meta-phosphor/conf/distro/include/phosphor-defaults.inc
index 600821093..30f1f7b55 100644
--- a/meta-phosphor/conf/distro/include/phosphor-defaults.inc
+++ b/meta-phosphor/conf/distro/include/phosphor-defaults.inc
@@ -19,8 +19,8 @@ PREFERRED_PROVIDER_virtual/obmc-sensor-mgmt ?= "obmc-phosphor-sensord"
 PREFERRED_PROVIDER_virtual/obmc-system-mgmt ?= "obmc-phosphor-sysd"
 PREFERRED_PROVIDER_virtual/obmc-settings-mgmt ?= "phosphor-settings"
 PREFERRED_PROVIDER_virtual/obmc-logging-mgmt ?= "phosphor-logging"
-PREFERRED_PROVIDER_virtual/obmc-host-state-mgmt ?= "phosphor-host-state-manager"
-PREFERRED_PROVIDER_virtual/obmc-chassis-state-mgmt ?= "phosphor-chassis-state-manager"
+PREFERRED_PROVIDER_virtual/obmc-host-state-mgmt ?= "phosphor-state-manager"
+PREFERRED_PROVIDER_virtual/obmc-chassis-state-mgmt ?= "phosphor-state-manager"
 
 OBMC_DBUS_PATH_ROOT ?= "/xyz/openbmc_project"
 OBMC_DBUS_IFACE_ROOT ?= "xyz.openbmc_project"