summaryrefslogtreecommitdiffstats
path: root/cf-code/cf-fsi-fw.S
blob: c0ca927218a92aa2d8b88b8c8047a8fb74ed66fc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
// SPDX-License-Identifier: GPL-2.0+

#include "cf-fsi-fw.h"

	.equ	SRAM_BASE_BE,	0x320000
	.equ	SRAM_BASE_LE,	0x720000
	.equ	GPIO_BASE,	0x780000
	.equ	CVIC_BASE,	0x6c2000

	.equ	STACK_SIZE,	0x100		/* 256 bytes of stack is enough */

	.equ	CVIC_STATUS,		0x00
	.equ	CVIC_SW_IRQ_CLR,	0x1c
	.equ	CVIC_SW_IRQ,		0x2

	.equ	FSI_PRE_BREAK_CLOCKS,	50	/* Number clocks to prep for break */
	.equ	FSI_BREAK_CLOCKS,	256	/* Number of clocks to issue break */
	.equ	FSI_POST_BREAK_CLOCKS,	16000	/* Number clocks to set up cfam */

	/* Register usage
	 *
	 * A0 : sratch/temp
	 * A1 : SRAM base (BE)
	 * A2:  CVIC address.
	 * A3:  TRACEBUF
	 * A4 : Data GPIO address
	 * A5 : Clock GPIO address
	 * A6 : CMD pointer
	 * A7 : Stack pointer
	 * D7 : clock/data/trans GPIO cache
	 * D6 : data/trans GPIO cache
	 * D5 : clock bit number
	 * D4 : data value
	 * D3 : loop counter
	 * D2 : command register
	 * D1 : scratch/temp
	 * D0 : scratch/temp
	 */

	/*
	 * Define clock/data GPIO cache registers and which
	 * register to use for trans GPIO in order to deal with
	 * potential overlaps
	 */
#define DCLK d7

#if CLOCK_GPIO_VREG == DATA_GPIO_VREG
#define DDAT d7
#else
#define DDAT d6
#endif

#if TRANS_GPIO_VREG == CLOCK_GPIO_VREG
#define DTRA d7
#elif TRANS_GPIO_VREG == DATA_GPIO_VREG
#define DTRA d6
#elif CLOCK_GPIO_VREG == DATA_GPIO_VREG
#define DTRA d6
#else
#define DTRA d1	/* Temp, not a cache */
#define DTRA_UNCACHED
#endif

	/* Tracing macro */

#ifdef ENABLE_TRACE
	.macro trace op:req
	move.b	\op,%a3@+
	.endm
	.macro count_clock
	addq.l	#1,%a1@(CLK_CNT)
	.endm
#else
	.macro trace op:req
	.endm
	.macro count_clock
	.endm
#endif

	/*
	 * Macros for clocking, sending and receiving
	 */

	/* clock_toggle: toggle the clock down and back up */
	.macro clock_toggle
	bclr.l	%d5,%DCLK	/* clock low */
	move.l	%DCLK,%a5@(0)
	bset.l	%d5,%DCLK	/* clock high */
	move.l	%DCLK,%a5@(0)
	count_clock
	.endm

	/* clock_out_bit reg: Clock out bit 31 of reg */
	.macro clock_out_bit reg:req
	btst.l	#31,\reg
	beq	98f
	bset.l	#DATA_GPIO_BIT,%DDAT
	trace	#TR_CLKOBIT1
	bra	99f
98:	bclr.l	#DATA_GPIO_BIT,%DDAT
	trace	#TR_CLKOBIT0
99:
	/* If data and clock GPIO share the same register, such as on
	 * Romulus, the write done by clock_toggle will set the new data
	 * value along with the low clock edge. Thus we don't need to
	 * set it here, thus saving a PCLK
	*/
#if DATA_GPIO_VREG != CLOCK_GPIO_VREG
	move.l	%DDAT,%a4@(0)
#endif
	clock_toggle
	.endm

	/* clock_zeros reg: Clock out zeros (GPIO set to 1), assume at least 1 */
	.macro clock_out_zeros reg:req
	trace	#TR_CLKZ
	trace	\reg
	bset.l	#DATA_GPIO_BIT,%DDAT
#if DATA_GPIO_VREG != CLOCK_GPIO_VREG
	move.l	%DDAT,%a4@(0)
#endif
99:	clock_toggle
	subq.l	#1,\reg
	bne	99b
	.endm

	/* clock_in_bit reg: Clocks in bit into bit 0 of reg, the rest is 0
	 * note: bit 0 of reg must already be cleared
	 */
	.macro clock_in_bit reg:req tmp:req tmp2:req
	bclr.l	%d5,%DCLK	/* clock low */
	move.l	%DCLK,%a5@(0)
#ifdef EXTRA_DUMMY_READ
	move.l	%a4@(0),\tmp		/* dummy read */
#endif
	move.l	%a4@(0),\tmp		/* dummy read */
	move.l	%a4@(0),\tmp		/* actual read */
	bset.l	%d5,%DCLK		/* clock high */
	move.l	%DCLK,%a5@(0)
	count_clock
	moveq.l	#DATA_GPIO_BIT,\tmp2
	lsr.l	\tmp2,\tmp
	moveq.l	#1,\tmp2
	and.l	\tmp2,\tmp
	or.l	\tmp,\reg
#ifdef ENABLE_TRACE
	move.l	#TR_CLKIBIT0,\tmp2
	or.l	\tmp,\tmp2
	trace	\tmp2
#endif
	.endm

	/*
	 * Beginning of code
	*/

	.text
	.org	0

	/*
	 * m68k exception Vectors
	 */
_vecs:
	/* Boot vector */
	.long	_stack_top		/* Stack below 1M */
	.long	_start			/* Start code */

	/* Remaining 254 vectors point to corresponding stubs
	 * starting at 0x10000, 0x10 bytes each
	 */
	.rept	254
0:	.long	_bad_exceptions + (0b - _vecs)
	.endr

	/*
	 * Header info
	 */
	.org	0x400
_header_info:
	.short	SYS_SIG			/* 0x00 */
	.short	FW_VERSION		/* 0x02 */
	.byte	API_VERSION_MAJ		/* 0x04 */
	.byte	API_VERSION_MIN		/* 0x05 */
	.byte	0,0			/* 0x06 pad */

#ifdef ENABLE_TRACE
#define _FW_OPTION_TRACE_EN	FW_OPTION_TRACE_EN
#else
#define _FW_OPTION_TRACE_EN	0
#endif

#ifdef CONTINUOUS_CLOCKING
#define _FW_OPTION_CONT_CLOCK	FW_OPTION_CONT_CLOCK
#else
#define _FW_OPTION_CONT_CLOCK	0
#endif
	.long	_FW_OPTION_TRACE_EN | _FW_OPTION_CONT_CLOCK	/* 0x08 */

	/*
	 * Config area
	*/
	.org	0x400 + HDR_CMD_STAT_AREA
_cmd_stat_base:
	.long	SRAM_BASE_BE

	/*
	 * Main entry point
	 */
	.org	0x500
	.global	_start
_start:
	/* Get base addresses */
	lea	%pc@(_cmd_stat_base),%a0
	movea.l	%a0@(0),%a1
	movea.l	#GPIO_BASE,%a4
	movea.l	%a4,%a5
	add.l	#CLOCK_GPIO_VREG,%a5
	add.l	#DATA_GPIO_VREG,%a4
	movea.l	#CVIC_BASE,%a2

	/* Store some diagnostic stuff */
	move.l			%d0,%a1@(CF_RESET_D0)
	move.l			%d1,%a1@(CF_RESET_D1)

	/* Cache clock bit number */
	moveq.l	#CLOCK_GPIO_BIT,%d5

	/*
	 * Check arbitration register early. There's a case where an arbitration request
	 * might have occurred right as we were starting the coprocessor. In that case,
	 * wait until we get back ownership
	 */
	move.b	%a1@(ARB_REG),%d2
	beq	1f

	/* Ack it */
	move.b	#ARB_ARM_ACK,%a1@(ARB_REG)

	/* Wait until it's cleared by the host */
0:	move.b	%a1@(ARB_REG),%d1
	bne	0b

1:	/*
	 * Load GPIO values into caches and set initial values
	 *
	 * Note: We load from the "Data Read" register which
	 *       contains the value of the write latch, and not
	 *       the "Value" register which, when read, returns
	 *       the value sampled on the line. The reason is that
	 *       the value can be missing recent changes due to
	 *       being behind synchronizers.
	 */
	move.l	%a5@(CLOCK_GPIO_DREG-CLOCK_GPIO_VREG),%DCLK
	move.l	%a4@(DATA_GPIO_DREG-DATA_GPIO_VREG),%DDAT
	move.l	%a5@(TRANS_GPIO_DREG-CLOCK_GPIO_VREG),%DTRA
	bset.l	#CLOCK_GPIO_BIT,%DCLK
	bset.l	#DATA_GPIO_BIT,%DDAT
	bset.l	#TRANS_GPIO_BIT,%DTRA
	move.l	%DCLK,%a5@(0)
	move.l	%DDAT,%a4@(0)
	move.l	%DTRA,%a5@(TRANS_GPIO_VREG-CLOCK_GPIO_VREG)

	/* Configure all GPIOs as output */
	move.l	%a5@(4),%d0
	bset.l	#CLOCK_GPIO_BIT,%d0
	move.l	%d0,%a5@(4)
	move.l	%a4@(4),%d0
	bset.l	#DATA_GPIO_BIT,%d0
	move.l	%d0,%a4@(4)
	move.l	%a5@(TRANS_GPIO_VREG-CLOCK_GPIO_VREG+4),%d0
	bset.l	#TRANS_GPIO_BIT,%d0
	move.l	%d0,%a5@(TRANS_GPIO_VREG-CLOCK_GPIO_VREG+4)

	/* Initialize A6 to point to command area */
	lea	%a1@(CMD_DATA),%a6

	/* Clear interrupt count */
	moveq.l	#0,%d0
	move.l	%d0,%a1@(INT_CNT)

	/* Install external interrupt vector */
	lea	%pc@(_int),%a0
	move.l	%a0,(0x46*4)

	/* Mask interrupts */
	move.w	#0x2007,%sr

	/* Configure GPIOs to output */
	bsr	config_gpio_out

	/* Indicate that we are started */
	mov3q.l	#0xffffffff,%a1@(CF_STARTED)

	/*
	 * Main command loop
	 */
main_loop:
	/* Reset trace pointer */
#ifdef ENABLE_TRACE
	lea	%a1@(TRACEBUF),%a3
#endif
	/* Wait arbitration request or command */
1:	move.b	%a1@(ARB_REG),%d2
	bne	arbitration_request
	move.l	%a1@(CMD_STAT_REG),%d2
	tst.b	%d2
	bne	command_request
#ifdef CONTINUOUS_CLOCKING
	clock_toggle
#else
#ifndef NO_SW_IRQ
	stop	#0x2000
	move.w	#0x2007,%sr
#endif
#endif
	bra	1b

arbitration_request:
	/* Ack request */
	move.b	#ARB_ARM_ACK,%a1@(ARB_REG)

	/* Wait until it's cleared by the host */
arb_wait:
	move.b	%a1@(ARB_REG),%d1
	beq	arb_done

#ifdef NO_SW_IRQ
	/* In absence of SW irq, just loop with some NOPs to avoid
	 * hammering the bus too hard
	 */
	moveq.l	#32,%d0
0:	nop
	subq.l	#1,%d0
	bne	0b
	bra	arb_wait
#else
	/* Wait, we'll get an interrupt when the host clears it */
	stop	#0x2000
	move.w	#0x2007,%sr
	bra	arb_wait
#endif

arb_done:
	/* Got it, re-load the GPIO caches */
	move.l	%a5@(0),%DCLK
	move.l	%a4@(0),%DDAT
#ifndef DTRA_UNCACHED
	move.l	%a5@(TRANS_GPIO_DREG-CLOCK_GPIO_VREG),%DTRA
#endif
	/* Reconfigure data as output just in case ... */
	bsr	config_gpio_out

	/* Back to main loop */
	bra	main_loop

command_request:
	/* Clear the command/status register */
	moveq.l	#0,%d0
	move.l	%d0,%a1@(CMD_STAT_REG)

	/* Start command ? */
	cmpi.b	#CMD_COMMAND,%d2
	beq	start_command

	/* Break command ? */
	cmpi.b	#CMD_BREAK,%d2
	beq	start_break

	/* Idle clocks command ? */
	cmpi.b	#CMD_IDLE_CLOCKS,%d2
	beq	start_idle_clocks

	/* Error */
	trace	#TR_END
	move.b	#STAT_ERR_INVAL_CMD,%a1@(CMD_STAT_REG)
	bra	main_loop

	/*
	 * Process a command
	 */
start_command:
	/* Start bit */
	moveq.l	#0,%d0
	clock_out_bit %d0
	trace	#TR_CLKOSTART

	/* Load first lword and invert it */
	move.l	%a6@(0),%d4
	not.l	%d4

	/* Shift command right to get bit count at bottom */
	lsr.l	#8,%d2

	trace	#TR_OLEN
	trace	%d2

	/* More than 32 ? If not go to tail
	 *
	 * Note: This assumes we have at least 1 bit to clock
	 */
	moveq	#32,%d3
	cmp.b	%d3,%d2
	blt	1f

	/* Clock out 32 bits */
	sub.l	%d3,%d2
0:	clock_out_bit %d4
	lsl.l	#1,%d4
	subq.l	#1,%d3
	bne	0b

	/* Get remaining bits */
	move.l	%a6@(4),%d4
	not.l	%d4

	/* Clock out what's left */
1:	moveq.l	#0,%d3
	move.b	%d2,%d3
	beq	2f
	trace	#TR_OLEN
	trace	%d3
0:	clock_out_bit %d4
	lsl.l	#1,%d4
	subq.l	#1,%d3
	bne	0b

2:	/* Done sending, ready to receive, first echo delay */
	move.b	%a1@(ECHO_DLY_REG),%d3 /* d3 is already 0 */
	clock_out_zeros %d3

	/* Set GPIO and transceivers to input */
	bsr	config_gpio_in

	/* Wait for start bit */
	move.l	#1000,%d3
	trace	#TR_CLKWSTART
0:	moveq	#0,%d4
	clock_in_bit %d4,%d0,%d1
	/* We read inverted value, so wait for a "0" */
	btst	#0,%d4
	beq	1f
	subq.l	#1,%d3
	bne	0b
	trace	#TR_END
	move.b	#STAT_ERR_MTOE,%a1@(CMD_STAT_REG)
	bra	send_delay

1:	/* Got start bit, clock in slave ID and response tag */
	trace	#TR_CLKTAG
	moveq	#4,%d3
	moveq	#0,%d4
0:	lsl.l	#1,%d4
	clock_in_bit %d4,%d0,%d1
	subq.l	#1,%d3
	bne	0b

	/* Invert data & trace*/
	not.l	%d4
	trace	%d4

	/* (not strictly needed: clean up top bits) */
	moveq	#0xf,%d0
	and.l	%d0,%d4

	/* Store into STAT_RTAG for host */
	move.b	%d4,%a1@(STAT_RTAG)

	/* Extract tag part */
	moveq	#0x3,%d0
	and.l	%d0,%d4

	/* If non-0, no data, go get CRC */
	bne	1f

	/* Do we expect data ? */
	lsr.l	#8,%d2
	beq	1f

	/* Let's get data. Assume no more than 32-bits */
	trace	#TR_CLKDATA
	trace	%d2
	move.l	%d2,%d3
	moveq.l	#0,%d4
0:	lsl.l	#1,%d4
	clock_in_bit %d4,%d0,%d1
	subq.l	#1,%d3
	bne	0b

	/* Invert data and store it */
	not.l	%d4
	move.l	%d4,%a1@(RSP_DATA)

1:	/* Grab CRC */
	trace	#TR_CLKCRC
	moveq.l	#4,%d3
	moveq.l	#0,%d4
0:	lsl.l	#1,%d4
	clock_in_bit %d4,%d0,%d1
	subq.l	#1,%d3
	bne	0b

	/* Invert it, extract 4 bits, and store it */
	not.l	%d4
	trace	%d4
	moveq.l	#0xf,%d0
	and.l	%d0,%d4
	move.b	%d4,%a1@(STAT_RCRC)

	/* End trace */
	trace	#TR_END

	/* Mark command complete */
	moveq.l	#STAT_COMPLETE,%d0
	byterev	%d0
	move.l	%d0,%a1@(CMD_STAT_REG)

send_delay:
	/* Send delay after every command */
	moveq.l	#0,%d3
	move.b	%a1@(SEND_DLY_REG),%d3
	clock_out_zeros %d3

	/* Configure GPIOs to output */
	bsr	config_gpio_out

	/* Next command */
	bra	main_loop

start_break:
	/* Clock some 1's to pace and flush out whatever's going on */
	move.l	#FSI_PRE_BREAK_CLOCKS,%d3
	clock_out_zeros %d3

	/* Clock out the break */
	moveq.l	#0,%d0
	clock_out_bit %d0
	move.l	#(FSI_BREAK_CLOCKS-1),%d3
0:	clock_toggle
	subq.l	#1,%d3
	bne	0b

	/* Clock some more 1's to resync (includes the send delay) */
	move.l	#FSI_POST_BREAK_CLOCKS,%d3
	clock_out_zeros %d3

	/* End trace */
	trace	#TR_END

	/* Mark command complete */
	moveq.l	#STAT_COMPLETE,%d0
	byterev	%d0
	move.l	%d0,%a1@(CMD_STAT_REG)

	bra	main_loop

start_idle_clocks:
	/* Shift command right to get bit count at bottom */
	lsr.l	#8,%d2

	/* Clock them out */
	moveq	#0,%d3
	move.b	%d2,%d3
	clock_out_zeros %d3

	/* End trace */
	trace	#TR_END

	/* Mark command complete */
	moveq.l	#STAT_COMPLETE,%d0
	byterev	%d0
	move.l	%d0,%a1@(CMD_STAT_REG)

	bra	main_loop

config_gpio_out:
	/* Configure data GPIO as output, value 1 (idle) */
	bset.l	#DATA_GPIO_BIT,%DDAT
	move.l	%DDAT,%a4@(0)
	move.l	%a4@(4),%d0
	bset.l	#DATA_GPIO_BIT,%d0
	move.l	%d0,%a4@(4)

	/* Set transceivers to output */
#ifdef DTRA_UNCACHED
	move.l	%a5@(TRANS_GPIO_DREG-CLOCK_GPIO_VREG),%DTRA
#endif
	bset.l	#TRANS_GPIO_BIT,%DTRA
	move.l	%DTRA,%a5@(TRANS_GPIO_VREG-CLOCK_GPIO_VREG)
	rts

config_gpio_in:
	/* Set transceiver to input */
#ifdef DTRA_UNCACHED
	move.l	%a5@(TRANS_GPIO_DREG-CLOCK_GPIO_VREG),%DTRA
#endif
	bclr.l	#TRANS_GPIO_BIT,%DTRA
	move.l	%DTRA,%a5@(TRANS_GPIO_VREG-CLOCK_GPIO_VREG)

	/* Configure data GPIO as input */
	move.l	%a4@(4),%d0
	bclr.l	#DATA_GPIO_BIT,%d0
	move.l	%d0,%a4@(4)
	rts

	/* Interrupt handler
	 *
	 * Note: Must only clobber %d0
	 */
_int:
	move.l	%d0,%a7@-
	addq.l	#1,%a1@(INT_CNT)
	moveq.l	#CVIC_SW_IRQ,%d0
	move.l	%d0,%a2@(CVIC_SW_IRQ_CLR)
	move.l	%a2@(CVIC_SW_IRQ_CLR),%d0
	move.l	%a7@+,%d0
	rte

	/* Bad exception handler */
bad_exception:
	move.l	%a7@+,%d0
	move.l	_bad_exceptions + 4,%d1
	sub.l	%d1,%d0
	lsr.l	#2,%d0
	move.b	%d0,%a1@(BAD_INT_VEC)
	move.b	#STAT_ERR_INVAL_IRQ,%a1@(CMD_STAT_REG)
	halt

	/* Bad exception stubs */
_bad_exceptions:
	.rept	256
	bsr.w	bad_exception
	.endr

	/* Stack */
	.balign	0x10
	.space	STACK_SIZE
_stack_top:
OpenPOWER on IntegriCloud